@echo off

REM Skrypt do aktualizacj map za pomoca protokolu rsync
REM Autor: Lukasz Michalski (lm @ zork.pl)
REM Potrzebne programy z katalogu narzedzia:
REM grep rsync cygwin1.dll [tlist|.vbs]

set UMP_SRC=rsync://rsync.ump.waw.pl/ump
rem latest-NI.txt NI, latest-og.txt ogonki, latest-to.txt topo
set WERSJA=latest-NI.txt
if exist wersja.bat call wersja.bat

REM sprawdzenie, czy mapsource dziala
rem tlist.exe | grep MapSource.exe > nul
wscript //nologo check-MS-run.vbs
if ERRORLEVEL 11 goto close_mapsource
if ERRORLEVEL 10 goto rsync
echo ======================
echo Nie da sie sprawdzic czy Mapsource dziala (blad!)
echo ======================
goto end_ng

:rsync
  echo ======================
  echo Pobieram uaktualnienia....
  echo Jak to okienko zniknie, to znaczy ze aktualizacja sie skonczyla.
  echo ======================

REM najpierw odczytanie nazwy katalogu
REM pobrany plik powinien mieæ 1 linie zawierajaca nazwe katalogu z aktualizacja
  rsync.exe %UMP_SRC%/%WERSJA% ./
  if ERRORLEVEL 1 (goto rsync_error)
  set /P UMP_LATEST=<%WERSJA%
  echo Poprawki z: %UMP_LATEST%
  
REM pobranie wlasciwych plikow
  rem jesli nie chcesz pliku *.typ, dodaj "--exclude=*.typ"
  rsync.exe -hrtz --progress --recursive %UMP_SRC%/%UMP_LATEST%/* ./
  if ERRORLEVEL 1 (goto rsync_error)
  echo ======================
  echo Zrobione
  echo ======================
  goto end_ok

:rsync_error
  echo ======================
  echo Nie udalo sie pobrac aktualizacji. 
  echo MAPA MOZE NIE DZIALAC.
  echo Sprobuj za jakis czas ponownie
  echo ======================
  goto end_ng

:close_mapsource
  echo ======================
  echo Zamknij MapSource przed aktualizacja.
  echo ======================

:end_ng
  ng.vbs
  goto end

:end_ok
  ok.vbs

:end
  del /q %WERSJA% 2> nul
  REM jak ktos patrzy, to niech zdazy zobaczyc speedup
  rem pause